You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

irqfile 1.9KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576777879808182838485
  1. .PAGE 'IRQFILE - DISPATCHER'
  2. ; SIMIRQ - SIMULATE AN IRQ (FOR CASSETTE READ)
  3. ; ENTER BY A JSR SIMIRQ
  4. ;
  5. SIMIRQ PHP
  6. PLA ;FIX THE BREAK FLAG
  7. AND #$EF
  8. PHA
  9. ; PULS - CHECKS FOR REAL IRQ'S OR BREAKS
  10. ;
  11. PULS PHA
  12. TXA
  13. PHA
  14. TYA
  15. PHA
  16. TSX
  17. LDA $104,X ;GET OLD P STATUS
  18. AND #$10 ;BREAK FLAG?
  19. BEQ PULS1 ;...NO
  20. JMP (CBINV) ;...YES...BREAK INSTR
  21. PULS1 JMP (CINV) ;...IRQ
  22. .SKI 5
  23. .PAG "IRQFILE-PATCHES 6/82"
  24. ; PCINT - ADD UNIVERSAL TO CINIT
  25. ;
  26. PCINT JSR CINT
  27. P0010 LDA VICREG+18 ;CHECK RASTER COMPARE FOR ZERO
  28. BNE P0010 ;IF IT'S ZERO THEN CHECK VALUE
  29. LDA VICREG+25 ;GET RASTER IRQ VALUE
  30. AND #$01
  31. STA PALNTS ;PLACE IN PAL/NTSC INDICATOR
  32. JMP IOKEYS
  33. ;
  34. ; PIOKEY - ADD UNIVERSAL TO IOKEYS
  35. ;
  36. PIOKEY LDA #$81 ;ENABLE T1 IRQ'S
  37. STA D1ICR
  38. LDA D1CRA
  39. AND #$80 ;SAVE ONLY TOD BIT
  40. ORA #%00010001 ;ENABLE TIMER1
  41. STA D1CRA
  42. JMP CLKLO ;RELEASE THE CLOCK LINE***901227-03***
  43. *=$E500-20
  44. ;
  45. ; BAUDOP - BAUD RATE TABLE FOR PAL
  46. ; .985248E6/BAUD-RATE/2-100
  47. ;
  48. BAUDOP .WOR 9853-CBIT ;50 BAUD
  49. .WOR 6568-CBIT ;75 BAUD
  50. .WOR 4478-CBIT ;110 BAUS
  51. .WOR 3660-CBIT ;134.6 BAUD
  52. .WOR 3284-CBIT ;150 BAUD
  53. .WOR 1642-CBIT ;300 BAUD
  54. .WOR 821-CBIT ;600 BAUD
  55. .WOR 411-CBIT ;1200 BAUD
  56. .WOR 274-CBIT ;1800 BAUD
  57. .WOR 205-CBIT ;2400 BAUD
  58. .PAGE "IRQFILE - PATCHES"
  59. *=$E500-32 ;(20-12)
  60. ; FPATCH - TAPE FILENAME TIMEOUT
  61. ;
  62. FPATCH ADC #2 ;TIME IS (8 TO 13 SEC OF DISPLAY)
  63. FPAT00 LDY STKEY ;CHECK FOR KEY DOWN ON LAST ROW...
  64. INY
  65. BNE FPAT01 ;KEY...EXIT LOOP
  66. CMP TIME+1 ;WATCH TIMER
  67. BNE FPAT00
  68. FPAT01 RTS
  69. .SKI 5
  70. *=$E500-38 ;(32-6)
  71. ; CPATCH - FIX TO CLEAR LINE...MODIFIED 901227-03
  72. ; PREVENTS WHITE CHARACTER FLASH...
  73. CPATCH ;ALWAYS CLEAR TO CURRENT FOREGND COLOR
  74. LDA COLOR
  75. STA (USER)Y
  76. RTS
  77. .SKI 5
  78. *=$E500-45 ;(38-7)
  79. ; PRTYP - RS232 PARITY PATCH...ADDED 901227-03
  80. ;
  81. PRTYP STA RINONE ;GOOD RECEIVER START...DISABLE FLAG
  82. LDA #1 ;SET PARITY TO 1 ALWAYS
  83. STA RIPRTY
  84. RTS
  85. .END